Displaying Syntax Components in Heading Objects

You can automatically display syntax components from your report or chart request in heading objects by adding one or more of the following attributes:

<REQUEST.FILTERS. Lists the WHERE and IF conditions in the request.
<REQUEST.VERB_OBJECTS. Lists the display fields referenced in the request.
<REQUEST.SORT_KEYS. Lists all sort fields in the request.
<REQUEST.BYKEYS. Lists all BY sort fields in the request.
<REQUEST.ACROSSKEYS. Lists all ACROSS sort fields in the request.
<REQUEST.VERB_OBJECTS_CONTEXT. Lists the display command syntax used for each display field.
<REQUEST.SORT_KEYS_CONTEXT. Lists all sort phrases in the request.

Note: The syntax component breaks onto multiple lines if the heading line length extends beyond the width of the report or chart container.

Example: Displaying Report Syntax Components

The following request displays all available syntax components from the report request in the heading. The spot markers (<+0>) are used to separate heading items so they can be styled separately in the StyleSheet.

TABLE FILE WF_RETAIL_LITE
HEADING
"Display Objects: <+0> <REQUEST.VERB_OBJECTS"
"Sort Fields: <+0> <REQUEST.SORT_KEYS"
"BY Fields: <+0> <REQUEST.BYKEYS"
"ACROSS Fields: <+0> <REQUEST.ACROSSKEYS"
"Filters: <+0> <REQUEST.FILTERS"
" "
"Display Commands: <+0> <REQUEST.VERB_OBJECTS_CONTEXT"
"Sort Phrases: <+0> <REQUEST.SORT_KEYS_CONTEXT
" "
" "
SUM COGS_US REVENUE_US 
COMPUTE RATIO/D12.2=REVENUE_US/COGS_US;
BY PRODUCT_CATEGORY SUBTOTAL COGS_US
ACROSS BUSINESS_REGION ACROSS-TOTAL
WHERE BUSINESS_REGION NE 'Oceania'
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT, COLOR = BLUE, SIZE=10, GRID=OFF,$
TYPE=HEADING, ITEM=1, OBJECT=TEXT, FONT=Courier, COLOR=BLUE, STYLE=BOLD,$
TYPE=HEADING, ITEM=2, FONT=Courier, COLOR=TEAL, STYLE=ITALIC,$
TYPE=TITLE, FONT=ARIAL, STYLE=BOLD, COLOR=NAVY,$
TYPE=ACROSSTITLE, FONT=ARIAL, STYLE=BOLD, COLOR=NAVY,$
TYPE=ACROSSVALUE, FONT=ARIAL, STYLE=ITALIC, COLOR=NAVY, SIZE=10,$
ENDSTYLE
END

The output is shown in the following image.

	WebFOCUS